試算表裡的 AI

試算表，是 AI 最常派上用場的地方

上一堂的自動化流程，動作常常是「寫進一份試算表」。其實不只自動化，大部分辦公室的資料，最後都住在 Excel 或 Google 試算表裡：報名名單、費用申請、銷售紀錄、問卷結果。

AI 在試算表裡可以幫上三種忙：

1. 幫你寫公式、解釋公式：不用背函式名稱，用中文描述你要什麼
2. 幫你清理資料：統一寫法、去掉多餘的空格、把文字變成數字
3. 試算表內建的 AI 功能：Google 試算表裡的 Gemini、Excel 裡的 Copilot，可以在側邊欄對話，有些版本還能在儲存格裡直接呼叫 AI

不管是哪一種，最後都要回到同一件事：驗算。試算表裡的數字常常會被拿去開會、做決定，錯了，是你要負責。

一個關鍵原則：讓 AI 寫公式，讓公式算數字

在「AI 工作力」單元，我們上傳表格請 AI 分析，再抽查驗算。在試算表裡，你有一個更好的選擇：請 AI 寫公式，而不是請它直接告訴你答案。

公式有三個好處：

• 看得到過程：點開儲存格就知道它怎麼算的，有疑問可以追
• 每次都一樣：同樣的資料，算出來永遠是同一個數字
• 可以重用：下個月貼上新資料，結果自動更新

練習資料：一份亂七八糟的費用表

假設你從公司系統匯出了一份費用申請表，想算出每個部門花了多少錢。打開一看：

A 日期	B 部門	C 項目	D 金額
2026/10/02	業務部	客戶餐敘	3,200
2026/10/03	業務 部	高鐵票	1490
2026/10/05	行銷部	廣告投放	NT$12,000
2026/10/08	Sales	計程車	350
2026/10/09	行銷	印刷	2,800

同一個部門有好幾種寫法，有的多了空格（還有全形空格），金額有的有逗號、有的有「NT$」。直接用樞紐分析，「業務部」會被拆成三個部門。這是真實世界裡非常常見的狀況。

第一步：用好問題換到好公式

請 AI 寫公式時，它看不到你的試算表，所以要把它需要的資訊講清楚。還記得五要素裡最重要的「背景」嗎？在這裡，背景就是欄位位置和資料長相。

注意這段指令沒有貼上真實資料，只描述了欄位和幾個例子。這樣既能拿到正確的公式，也不會把公司的資料交出去。

你會拿到類似這樣的公式：

E2：=SUBSTITUTE(SUBSTITUTE(B2," ",""),"　","")
G2：=VALUE(SUBSTITUTE(SUBSTITUTE(D2,"NT$",""),",",""))

• E2：SUBSTITUTE 是「取代」。內層把半形空格換成空的，外層再把全形空格換成空的。常見的 TRIM 函式只會處理頭尾和重複的半形空格，處理不了「業務 部」中間的空格和全形空格，所以這裡用取代。
• G2：先把「NT$」和逗號都拿掉，剩下「12000」這樣的文字，再用 VALUE 轉成真正的數字。

把公式往下複製到最後一列。

第二步：用對照表統一名稱

去掉空格之後，還剩「Sales」和「業務部」、「行銷」和「行銷部」這種寫法不同的問題。這種事，與其讓公式去猜，不如做一張對照表，把規則寫得清清楚楚。

1. 新增一張工作表，取名「對照表」。
2. 在 A1 輸入 =UNIQUE(費用表!E2:E500)，列出 E 欄所有不重複的寫法（工作表名稱換成你的）。
3. 在旁邊的 B 欄，手動填上每一種寫法對應的標準名稱。寫法很多的話，可以把 A 欄複製給 Claude，請它建議對應方式，但每一列都要你自己看過。

A 原本的寫法	B 標準名稱
業務部	業務部
Sales	業務部
行銷部	行銷部
行銷	行銷部

小提醒：UNIQUE 的結果會隨資料變動。對照表定案後，可以把 A 欄複製、用「只貼上值」固定下來，免得之後資料一變，A 和 B 就錯位了。

回到費用表，在 F2 用 XLOOKUP 查對照表：

F2：=XLOOKUP(E2, 對照表!A:A, 對照表!B:B, "未對應")

意思是：「拿 E2 去對照表的 A 欄找，找到了，就回傳同一列 B 欄的標準名稱；找不到，就顯示『未對應』。」

最後那個「未對應」非常重要。下個月出現一個新寫法「業務一部」，它不會被悄悄算錯，而是會大聲地顯示「未對應」，提醒你去補對照表。

每一步都是新的一欄，出問題時可以一欄一欄往回找。

第三步：統計各部門

在旁邊列出部門名稱（例如 I2 是「業務部」、I3 是「行銷部」），在 J2 輸入：

J2：=SUMIFS(G:G, F:F, I2)

意思是：「把 G 欄的金額加起來，但只加 F 欄等於 I2 的那幾列。」往下複製，每個部門的總額就出來了。

第四步：驗算三招

公式算出來了，不代表是對的。公式可能寫錯範圍，對照表可能漏了一種寫法。交出去之前，花三分鐘做這三件事：

1. 總數對得上。 各部門加總的合計，要等於全部金額的合計：

=SUM(J2:J10)     各部門加總的合計
=SUM(G:G)        全部金額的合計

兩個數字不一樣，就代表有某些列沒有被算到任何部門裡。

2. 找不到對應的筆數是 0。

=COUNTIF(F:F, "未對應")

不是 0，就去篩選出那幾列，把新的寫法補進對照表。

3. 隨機抽三列手算。 挑三列，特別是長得奇怪的（有「NT$」的、有全形空格的），用眼睛和計算機確認 E、F、G 三欄的結果都對。

這三招跟你在「AI 工作力」單元學過的「抽查驗算」是同一個精神，只是在試算表裡，你可以用公式讓檢查自動化。

試算表內建的 AI 功能

Google 試算表和 Excel 都陸續加入了 AI 功能，可用的範圍和方案常常改變，請到官方說明確認你的版本有哪些。常見的用法有兩種：

側邊欄助理。 用中文要它「做一張各部門費用的樞紐分析表」「這份資料有哪些異常值」。它會直接幫你操作試算表。用完要確認它改了什麼：新增了哪些工作表、有沒有動到原始資料。

儲存格裡的 AI 函式。 有些版本可以在儲存格裡寫一個公式，讓 AI 處理那一格的文字。它最適合模糊、靠理解的工作，例如把一欄自由填寫的問卷意見，分類成「價格、品質、服務、其他」。

使用時要注意：

• AI 函式重新計算時，結果可能改變，而且通常有使用次數的限制。分類確定之後，把結果複製、用「只貼上值」固定下來。
• 用之前，先拿 10 列測試，人工檢查分類對不對，再套用到全部。
• 那一欄的內容會被送去 AI 處理，含有個資的欄位不要用。

至於加總、比對、轉換格式這種規則清楚的工作，還是用一般的公式，又快又準，也不花 AI 的額度。